project('lcppthw', 'cpp',
    default_options: ['cpp_std=c++20'])

cmake = import('cmake')
opts = cmake.subproject_options()
opts.add_cmake_defines({
  'USE_ICONV': false,
  'USE_SSH': false,
  'USE_NTLMCLIENT': false,
  'BUILD_SHARED_LIBS': true,
  'BUILD_TESTS': false,
  })
libgit2_proj = cmake.subproject('libgit2', options: opts)
libgit2package_dep = libgit2_proj.dependency('libgit2package')

efsw_proj = cmake.subproject('efsw')
efsw_dep = efsw_proj.dependency('efsw')

fmt = dependency('fmt')
ftxui_screen = dependency('ftxui-screen')
ftxui_dom = dependency('ftxui-dom')
ftxui_component = dependency('ftxui-component')
doctest = dependency('doctest')

dependencies = [
  fmt, libgit2package_dep, efsw_dep,
  ftxui_screen, ftxui_dom, ftxui_component
]

executable('escape_turings_tarpit',
  'escape_turings_tarpit.cpp',
  dependencies: dependencies)

executable('regtest', 'regtest.cpp',
  dependencies: [fmt])

executable('ftxtest', 'ftxtest.cpp',
  dependencies: dependencies)

executable('ftx_thread_test', 'ftx_thread_test.cpp',
  dependencies: dependencies)

executable('tests', [
  'tests/test1.cpp'],
  dependencies: dependencies + [doctest])